TEXT() – Funktion

Die Text-Funktion TEXT()

Beschreibung

Diese Funktion wandelt als Argument übergebene Zahlen (numerischer Wert) in formatierten Text um. Das Ergebnis ist dann ein Text, welcher in den meisten Fällen mit weiteren Textpassagen verknüpft wird.

Syntax

 =TEXT(Wert; „TextFormat“)

Argument(e)

Das erforderliche Argument Wert ist eine Zahl oder ein Wert, der von Excel als Zahl oder als Datum/Uhrzeit interpretiert werden kann. Wenn Sie ganz normalen Text als Parameter verwenden, dann wird dieser ohne weitere Formatierung genau so wieder ausgegeben.

Mit dem ebenfalls nicht optionalen Argument „TextFormat“ wird beschrieben, welche Formatierung (dem Zahlenformat entsprechend) der Rückgabetext haben soll.

▲ nach oben …

Beispiel: In A1 steht ein Wert von 110, welcher als Währung formatiert ist. Auf dem Bildschirm sehen Sie dann: 110,00 €. In beispielsweise D25 wollen Sie Bezug auf diesen Preis nehmen und schreiben:
=“Der Zimmerpreis beträgt “ & A1 & “ pro Nacht.“

Das  Ergebnis wird unbefriedigend sein, denn dort steht dann:
Der Zimmerpreis beträgt 110 pro Nacht.

Das Zahlenformat wurde nicht übernommen. In solchen Fällen kommt dann die Funktion TEXT() zum Zuge. Geben Sie die Formel exakt so ein, mit den Anführungsstrichen:
=“Der Zimmerpreis beträgt “ & TEXT(A1; „#.##0,00 €“) & “ pro Nacht.“
und die Ausgabe wird sogar bei Beträgen über 1.000,00 € so sein, dass ein Tausenderpunkt eingefügt wird.

Die folgenden Tabellen zeigen die verschiedenen Möglichkeiten auf, das Argument „TextFormat“ einzusetzen.

Vorgaben für ein TextFormat (Zahlenformat)

Wie auch beim normalen Zahlenformat gibt es verschiedene Platzhalter für unterschiedliche Ergebnisse:

PlatzhalterBeschreibung / Hinweise
0 (Null)Diese Ziffer an der Position wird in jedem Fall mit ausgegeben. Beispielsweise feste Anzahl von Nachkommastellen oder auch auf n Stellen vor dem Komma erforderlichenfalls mit Nullen auffüllen.
#Die Raute ist ein Lückenfüller, um beispielsweise den Tausenderpunkt zu positionieren. Ziffern ungleich 0 werden stets angezeigt, führende Nullen werden nicht berücksichtigt. Der Tausenderpunkt wird nur dann angewendet, wenn die Zahl groß genug ist.
?Fügt pro Fragezeichen links bzw. rechts des Kommas einer Zahl 1 Leerstelle links bzw. rechts außen hinzu, dass die Ausrichtung des Kommas in untereinander liegenden Spalten identisch ist.
, (Komma)Das Dezimalzeichen, wie es hier in Deutschland verwendet wird. - Komma und Punkt sind bei anderen Ländereinstellungen des Betriebssystems unter Umständen vertauscht!

Beispiele für Zahlen

Wert (Zahl)ZeichenFormatErgebnis
12345,67"0,0#"12345,67
12345,67"#.##0,00"1.2345,67
12345,67"#.##0,0"1.2345,7
12,345"#.#"12,3
12,345"#,##"12,345
12,345"000,00"012,35
12,345""(nichts, leer)
12,345
654,32
,1
Jeweils
"???,???"
Nur bei Schriften mit fester Zeichenbreite OK, siehe Abbildung/Kommentar hierunter.
2,75
19,85
jeweils
"# #/#"
2 3/4
19 6/7
(als Bruchzahl)
0,4"#,#",4
10050000
(10.500.000)
TEXT(A1;"#,0..") &
" Mio. €"
10,5 Mio. €
(Die Punkte nach dem Komma sind entscheidend!)

Hinweise zur Tabelle hierüber

3. Zeile, Zahl: 12345,67 | Format: „#.##0,0″
Da nach dem Komma nur 1 Null und keine Raute # als Platzhalter steht, wurde der Ausgabewert kaufmännisch gerundet.

4. Zeile, Zahl: 12,345 | Format: „#,#“
Eine ähnliche Konstellation wie vor. Auch hier ist nach dem Komma nur 1 Platzhalterzeichen angegeben. Da die zweite Ziffer nach dem Komma eine 4 ist, wird abgerundet.

5. Zeile, Zahl: 12,345 | Format: „#,##“
An 2. Stelle ist ein Komma (in der Tabelle nicht so gut zu erkennen). Wegen der Raute werden die restlichen, überzähligen Nullen nicht angezeigt.

6. Zeile, Zahl: 12,345 | Format: „000,00″
Wegen der 3 führenden Nullen vor dem Komma wird das Ergebnis auch mit (mindestens) 3 Stellen ausgegeben.

8. Zeile, Zahl: (mehrere) | Format: “???,???“
Es wird tatsächlich für jedes Fragezeichen entweder eine Ziffer oder ein Leerzeichen dargestellt. Aber das funktioniert (leider) nur, wenn eine Zeichensatz verwendet wird, wo jedes Zeichen gleich breit ist (wie in der Urzeit der Computer 🙁 ):

Teils fehlerhafte Darstellung

Es ist nicht alles Gold, was glänzt …

Spalte A sind die Zahlen, Spalte B ist die Schriftart Courier New und in der 3. Spalte die normale Schriftart in Excel. Sie sehen, dass die Zahlenausrichtung in der 2. Spalte so ist, wie beschrieben; die Kommas stehen immer an der gleichen Position. Spalte C hat genau das gleiche TextFormat, allerdings ist dort nicht jedes Zeichen so breit wie ein Leerzeichen, was dadurch nicht zum gewünschten Ergebnis führt.

11. Zeile (evtl. blättern), Zahl: 10050000 | Funktion: TEXT(A1;“#,0..“) & “ Mio. €“
Wegen der außergewöhnlichen Formatierung ist hier die komplette Formel dargestellt. Zehn Millionen, Fünfhunderttausend ist die Ursprungszahl. Durch das TextFormat „#,0..“ wird das Komma um 6 Stellen nach links verschoben. (Die Punkte sind hier in rot dargestellt, damit sie deutlicher sichtbar sind.) Der Zusatz “ Mio. €“ muss außerhalb der TEXT()-Funktion angehängt werden.

Beispiele für kalendarische Daten

Zeit - BereichZeichenFormatErgebnis
Jahre"JJ"00 .. 99
Jahre"JJJJ"1900 .. 9999
Tage"t"1 .. 31
Monate"M"1 .. 12
Monate"MM"01 .. 12
Monate"MMM"Jan .. Dez
(ohne Punkt)
Monate"MMMM"Januar .. Dezember
Monate"MMMMM"J .. D
Tage"tt"01 .. 31
Tage"ttt"Mo .. So
(ohne Punkt)
Tage"tttt"Montag .. Sonntag
(ab hier: Zeiten)
Stunden"h"0 .. 23
Stunden"hh"00 .. 23
Stunden"[h]"0 .. >10.000
Stunden"[hh]"00 .. >10.000
Minuten"m"0 .. 59
Minuten"mm"00 .. 59
Minuten"[m]"0 .. >10.000
Minuten"[mm]"00 .. >10.000
Sekunden"s"0 .. 59
Sekunden"ss"00 .. 59
Sekunden"[s]"0 .. >10.000
Sekunden"[ss]"00 .. >10.000
Gesamt Stunden:Minuten"[hh]:mm"123:45
Gesamt Minuten:Sekundenen"[mm]:ss"123:45
Gesamt Sekunden:n/100 Sek."[ss],00"4567,89

Zugegeben, das sind einige Möglichkeiten. Und es sind noch nicht alle. Die ganze US-Schreibweise (AM/PM) habe ich weg gelassen und noch einige unbedeutende Formate. Da bitte einfach einmal in der Hilfe nachschauen. Insgesamt ist hier etwas Experimentierfreudigkeit gefragt, dann werden Sie rasch zum gewünschten Ziel gelangen. Im Verzweifelungsfall fragen Sie gerne bei uns an, unser Sponsor GMG-CC bietet Ihnen zu fairen Konditionen eine Lösung an.

▲ nach oben …

 

 

Dieser Beitrag wurde unter Excel-Funktionen, Text abgelegt und mit , , , verschlagwortet. Setze ein Lesezeichen auf den Permalink.